A Digital Workflow for Academic ResearchBibDesk Archives » A Digital Workflow for Academic Research

MediaWiki, Mac and custom URL schemes

A lot of Mac applications have their own URL schemes. In the following table you can see some examples of custom URL schemes:

Application	Custom URL scheme
Evernote	evernote://
DEVONthink	x-devonthink://
BibDesk	x-bdsk://
OmniFocus	omnifocus://
VoodooPad	x-voodoopad-item://
TextMate	txmt://

If you want to see all URL scheme handlers on your system you can install the freeware app RCDefaultApp. Also handleopenurl.com maintains a URL scheme index of more than 600 iOS apps.

Custom URL schemes are extremely valuable because you can address specific data of an application by using them. They are the basic building blocks of all hyperlinks. In my post “Automated summary creation linked with the source PDF file” you can see how I use x-devonthink URL schema in order to connect my notes with the source PDF file.

Moreover, as you can see in my post “Embed AppleScripts in a MediaWiki page” there is a custom URL scheme for AppleScript! In my next posts I will publish a series of AppleScripts, which use the “applescript://” URL scheme.

MediaWiki can recognize all these custom URL schemes if you add the following lines in the LocalSettings.php file:

$wgUrlProtocols[] = “evernote://”;
$wgUrlProtocols[] = “devonthink://”;
$wgUrlProtocols[] = “x-bdsk://”;
$wgUrlProtocols[] = “omnifocus://”;
$wgUrlProtocols[] = “x-voodoopad-item://”;
$wgUrlProtocols[] = “txmt://”;
$wgUrlProtocols[] = “applescript://”;

You can see my post “How to use DevonThink links in a MediaWiki page” for more detailed information.

Dec 2011

AUTHOR John Sidiropoulos

CATEGORY

all my posts, AppleScript, BibDesk, DevonThink, Mac, MediaWiki, TextMate

COMMENTS No Comments

Send DEVONthink tags to BibDesk as keywords

Continuing in the same spirit as in the previous post, I wrote an AppleScript for sending DEVONthink tags to BibDesk. Only one item should be selected in DEVONthink and BibDesk. No duplicate keywords are created in BibDesk.The AppleScript code is the following:

Click here to see the source code

tell application "BibDesk"
--only one item should be selected in BibDesk
set thePub to the selection of document 1
set keywordsPub to keywords of (item 1 in thePub)
set old_delimiters to AppleScript's text item delimiters
--the space inside quotes is very important!
set AppleScript's text item delimiters to ", "
set keywordsPubList to text items of keywordsPub
set AppleScript's text item delimiters to old_delimiters
end tell
�
tell application "DEVONthink Pro"
set thisSelection to the selection
if thisSelection is {} then error "Please select something"
if (length of thisSelection) is greater than 1 then error "Please select only one item"
set the clipboard to ""
set thisItem to (item 1 of thisSelection)
set tagsItem to tags of thisItem
repeat with x from 1 to the count of tagsItem
set positionOfDuplicate to list_position(item x of tagsItem, keywordsPubList) of me
if positionOfDuplicate is 0 then
set keywordsPub to keywordsPub & ", " & item x of tagsItem
else
set keywordsPub to keywordsPub
end if
end repeat
end tell
tell application "BibDesk"
if the first character of keywordsPub is "," then
set keywordsPub to text 3 thru -1 of keywordsPub as text
end if
set keywords of (item 1 in the thePub) to keywordsPub
end tell
�
--subroutine from "AppleScript 1-2-3" p.567 for checking for duplicates
on list_position(this_item, this_list)
repeat with i from 1 to the count of this_list
if item i of this_list is this_item then return i
end repeat
return 0
end list_position

Jun 2011

AUTHOR John Sidiropoulos

CATEGORY

all my posts, AppleScript, BibDesk, DevonThink

COMMENTS No Comments

Add keywords to many entries of BibDesk at the same time

The following AppleScript performs the above function:

Click here to see the source code

tell application "BibDesk"
    set theSelection to the selection of document 1
    display dialog "Give the new keywords separated by commas:" default answer "" buttons {"Cancel", "OK"} default button 2
    set the newKeywords to the text returned of the result
 
    repeat with thePub in theSelection
        set oldKeywords to keywords of thePub
        if oldKeywords is "" then
            set keywords of thePub to newKeywords
        else
            set keywords of thePub to keywords of thePub & ", " & newKeywords
        end if
    end repeat
end tell

Jun 2011

AUTHOR John Sidiropoulos

CATEGORY

all my posts, AppleScript, BibDesk

COMMENTS No Comments

How to automatically embed hyperlinks into citations and bibliographical entries of a downloaded PDF document! Part II

How to create the dictionaries

Firstly your ebooks and papers should be inside inside a DevonThink database. Moreover each source should have its respective record in BibDesk. The “local URL” field of each record should have the DevonThink URL of the source. If you do not know how to do this you can read my post “How to connect a PDF file inside DevonThink with its record in BibDesk“. Finally you should select the records in BibDesk which will constitute the records of the dictionary and you should have one TextMate txt file open. Now you are ready to execute either the AppleScript for the creation of the link dictionary with the titles or for the second kind of dictionary.The AppleScript code for the link dictionary with the titles is the following:

Click here to see the source code

--2011-03-11
    --http://organognosi.blogspot.com
 
    --Works with AutoBookmark 3.7
 
    tell application "BibDesk"
        set these_items to the selection of document 1
        if these_items is {} then error "Please select some contents."
 
        repeat with this_item in these_items
            set DevonThinkLink to the linked URL 1 of this_item
            set PDfTitle to the value of the field "Title" of this_item
            set keywords of this_item to keywords of this_item & "," & " title link"
            set DictionaryLinkEntry to PDfTitle & tab & "uri:" & DevonThinkLink & "
    "
            tell application "TextMate"
                activate
                insert DictionaryLinkEntry
            end tell
        end repeat
    end tell

A sample from the text which can be created is shown below:

The AppleScript code for the link dictionary with author-year compinations is the following:

Click here to see the source code

--2011-03-11
    --http://organognosi.blogspot.com
 
    --Works with AutoBookmark 3.7
 
    tell application "BibDesk"
        set these_items to the selection of document 1
        if these_items is {} then error "Please select some contents."
 
        repeat with this_item in these_items
            set DevonThinkLink to the linked URL 1 of this_item
            set PDfTitle to the value of the field "Title" of this_item
            set keywords of this_item to keywords of this_item & "," & " title link"
            set DictionaryLinkEntry to PDfTitle & tab & "uri:" & DevonThinkLink & "
    "
            tell application "TextMate"
                activate
                insert DictionaryLinkEntry
            end tell
        end repeat
    end tell

A sample from the text which can be created is shown below:

The AppleScript code for the link dictionary with author-year compinations is the following:

Click here to see the source code

--2011-03-11
    --http://organognosi.blogspot.com
 
tell application "BibDesk"
    set these_items to the selection of document 1
    if these_items is {} then error "Please select some contents."
 
    repeat with this_item in these_items
        try
            set AuthorLink to the last name of the first author of this_item
            set firstNameLink to the first name of the first author of this_item
            set AbbrNormName to abbreviated normalized name of the first author of this_item
 
            set YearLink to the publication year of this_item
            set DevonThinkLink1 to the linked URL 1 of this_item
            set DictionaryLinkEntry to AuthorLink & " " & YearLink & tab & "uri:" & DevonThinkLink1 & "
"
            set DictionaryLinkEntry2 to AuthorLink & " (" & YearLink & tab & "uri:" & DevonThinkLink1 & "
"
            set DictionaryLinkEntry3 to AuthorLink & " [" & YearLink & tab & "uri:" & DevonThinkLink1 & "
"
            set DictionaryLinkEntry4 to AuthorLink & ", " & firstNameLink & " (" & YearLink & tab & "uri:" & DevonThinkLink1 & "
"
            set DictionaryLinkEntry5 to AbbrNormName & " " & YearLink & tab & "uri:" & DevonThinkLink1 & "
"
            set DictionaryLinkEntry6 to AbbrNormName & " (" & YearLink & tab & "uri:" & DevonThinkLink1 & "
"
 
            tell application "TextMate"
                activate
                insert DictionaryLinkEntry
                insert DictionaryLinkEntry2
                insert DictionaryLinkEntry3
                insert DictionaryLinkEntry4
                insert DictionaryLinkEntry5
                insert DictionaryLinkEntry6
            end tell
        end try
    end repeat
end tell

A sample from the text which can be created is shown below:

Now you are ready to go to Adobe Acrobat Pro and use the AutoBookmark plug-in. In the following screen shots you can see the detailed steps in order to create the new dictionaries.

In this step you should select the txt file which was created by one of the two AppleScripts

Now your link dictionary is ready.

Mar 2011

AUTHOR John Sidiropoulos

CATEGORY

Adobe Acrobat Pro, all my posts, AppleScript, AutoBookmark, BibDesk, DevonThink, hyperlink, PDF, TextMate, virtual machine, Windows

COMMENTS 1 Comment

How to automatically embed hyperlinks into citations and bibliographical entries of a downloaded PDF document! Part I

Nowadays, it is possible for a researcher to amass a huge number of electronic papers and books about his specialized area of interest. Naturally there are a lot of cross-references between these sources. The usual way of managing these files is the creation of a bibliographical database in one of the numerous relative programs like EndNote, Papers, JabRef and BibDesk. In this post I will try to present an exciting new way of “managing” your files which in a way makes managing them obsolete!Specifically I created a workflow for embedding DevonThink hyperlinks into the very citations and bibliography entries of a PDF file. As a result when you want to read a cited paper or book you do not need to go to your bibliography manager program or even worse to the folder hierarchy of your hard drive in order to find the file. Instead you can just click the citation or the title or the author of the bibliography entry and the respective PDF file opens instantly! The magic of DevonThink hyperlinks in action!

The required tools/programs for this dream to come true are the following:

Adobe Acrobat Pro for Windows
AutoBookmark plug-in for Adobe Acrobat Pro
A Windows virtual machine
DevonThink
BibDesk
TextMate
Link dictionaries
The AppleScripts for creating automatically the link dictionaries from BibDesk

More details about the workflow

AutoBookmark searches page text for occurrences of specific words or phrases and generates links annotations according to the user specifications. Link dictionary is a collection of search terms (words, phrases and etc.) and corresponding link actions. When it finds a search term from a dictionary it automatically creates a link annotation using a link action that is associated with it. Each search term should be unique within a link dictionary (excerpt from AutoBookmark help file). So you need to have an appropriate link dictionary so as the hyperlinks to the sources to be created automatically by AutoBookmark.

For our case I consider optimal the use of two different dictionaries each with its own advantages and disadvantages. The first contains various possible forms of author-year citations e.g. Clark 2008, Clark (2008, Clark Stephen (2008, Clark S. 2008, Clark S. (2008. The advantage of this dictionary is that the matches are almost 100% unique. However the probability of the match is somewhat small because of the high variability in the way that the citations are made. The second contains the source titles. Now the situation is the complete opposite because you can very easily have false positive matches if the title is too generic but there is no case of a missing match if the title is adequately complex.

In my next post I will describe how you can create the link dictionaries from your Mac.

Mar 2011

AUTHOR John Sidiropoulos

CATEGORY

Adobe Acrobat Pro, all my posts, AutoBookmark, BibDesk, DevonThink, hyperlink, PDF, TextMate, virtual machine, Windows

COMMENTS 2 Comments

How to connect a PDF file inside DevonThink with its record in BibDesk

I use BibDesk to manage and create my bibliographies but all my read and annotated PDF files are inside DevonThink. So I wanted an easy and fast way to connect the PDF files with their respective records in BibDesk. Technically I wanted to populate the “local URL” and “local File” columns of BibDesk. Consequently I wrote an AppleScript which does this job.

Moreover this AppleScript assigns the tag/keyword “Linked with DevonThink” to the record in which is applied. In order for this script to work properly you just have to select one PDF file in DevonThink and its respective bibliography record in BibDesk.The AppleScript code is the following:

Click here to see the source code

--2011-03-08
--http://organognosi.blogspot.com
--the script works only for one PDF file per time
 
tell application "DEVONthink Pro"
    set this_item to the content record of think window 1
    set RecordLink to the reference URL of this_item
    set DevonThinkLink to RecordLink & "?page=0"
    set PdfPath to get the path of this_item
    set PdfPath to (POSIX file PdfPath) as alias
 
    tell application "BibDesk"
        activate
        set these_items to the selection of document 1
        repeat with theBook in these_items
            add DevonThinkLink to linked URL of theBook
            add PdfPath to linked files of theBook
            set currentKeywords to get keywords of theBook as string
            if (currentKeywords is not "") then
                set delimiter to ", "
            else
                set delimiter to ""
            end if
            set keywords of theBook to (keywords of theBook & delimiter & "Linked with DevonThink")
        end repeat
    end tell
 
end tell

Mar 2011

AUTHOR John Sidiropoulos

CATEGORY

all my posts, AppleScript, BibDesk, DevonThink

COMMENTS 2 Comments

Some tools of the trade

I use the following hardware:

a MacBook Pro 17in
a MacMini (as a server for my wikis and my ebooks library)
an iPad
a Time Capsule
an iPhone 3G
several external hard drives (for backup)
a 27in LG monitor

In my academic workflow I use the following programs:

Skim: for reading papers and books (in pdf format)
Calibre: for organizing all my ebooks (read and unread)
DevonThink: for organizing everything that I have read
BibDesk: for reference management and automated bibliography creation
MediaWIki: for notes management
TextMate and LaTex: for writing my papers
AppleScript: for automating my workflow

Feb 2011

AUTHOR John Sidiropoulos

CATEGORY

all my posts, BibDesk, Calibre, DevonThink, iPad, IPhone, LaTeX, Mac mini, MacBook Pro, MediaWiki, Skim, TextMate, the big picture

COMMENTS 1 Comment

A Digital Workflow for Academic Research
Tools for Knowledge and Knowledge for Tools

Recently Twitted

All my posts

Tags

Blogroll